Ajitabh Pandey's Soul & Syntax

Exploring systems, souls, and stories – one post at a time

Tag: perl

  • Build An MP3 Catalogue System With Perl – Conclusion

    In the last post we saw how to read ID3v1 and ID3v2 tags using perl. In this post we will continue our journey towards creating a simple catalog for the MP3 collection.

    Quickly Getting the Desired Information out of the MP3 – autoinfo()

    Usually in my catalog I am interested in the following information about an MP3 – Title, Artist, Album, Track, Year, Genre, Comment and the Artwork. However, I do not want to loop through all available information in my program to get this data. Fortunately the MP3::Tag module provides a autoinfo() function which gets almost all the information needed for us except the Artwork, which we may need to gather separately. The autoinfo() function returns the information about the title, album, artist, track, tear, genre and comment. This information is obtained from ID3v2 tag, ID3v1 tag, CDDB file, .inf file and the mp3 filename itself, where-ever it is found first. The order of this lookup can be changed with the config() command. I want to restrict my cataloging to only ID3v2  and ID3v1 tags.

    Following lines provides us with the needed information.

    $mp3->config("autoinfo", "ID3v2", "ID3v1");
my ($title, $track, $artist, $album, $comment, $year, $genre) = $mp3->autoinfo();

    Getting Artwork Information

    The artwork information is stored in the ID3v2 tag in a frame called APIC (stands for Attached PICture). This frame has _Data and MIME Type which we would need for our purpose. In order to extract this frame and its data we do not need to loop in through all the tags. The MP3::Tag module provides us with the get_frame() method, using which we can extract any frame directly like as shown below for artwork –

    my $apic_frame = $mp3->{ID3v2}->get_frame("APIC");
my $img_data = $$apic_frame{'_Data'};
my $mime_type = $$apic_frame{'MIME type'};

    This $img_data can be written out in a file and the $mime_type can be used as an extension. Thus we can extract the artwork from the MP3 file. The MIME type is something like “image/jpeg” and I have used the split function to get the string for the extension of the file.

    my ($mime1, $mime2) = split(/\//, $mime_type);
my $artwork_name = "artwork.$mime2";
open ARTWORK_FILE, ">$artwork_name" 
  or die "Error creating the artwork file";
binmode(ARTWORK_FILE);
print ARTWORK_FILE $img_data;
close ARTWORK_FILE;

    Generating the HTML using HTML

    This is a simple project so I have used HTML::Template module to generate HTML code to the standard output, which can then in turn be redirected to a file using shell redirection. For a making the table layout less cumbersome, I have used the purecss.io CSS framework. Here my HTML template code.

    my $template = <<HTML;
<html>
<head>
<title>My MP3 Catalog</title>
<link rel="stylesheet" href="http://yui.yahooapis.com/pure/0.5.0/pure-min.css">
</head>
<body>
<h1>My MP3 Collection</h1>
<table class="pure-table pure-table-horizontal">
    <thead>
        <tr>
            <th>Album Artwork</th>
			<th>Album</th>
            <th>Track</th>
            <th>Title</th>
            <th>Artist</th>
			<th>Year</th>
			<th>Genre</th>
			<th>Comment</th>
        </tr>
    </thead>

    <tbody>
		<!-- TMPL_LOOP NAME=SONGS -->
		<tr>
			<td><a src="<TMPL_VAR NAME=FILEPATH>"><img src="<TMPL_VAR NAME=IMG>" height="150" width="150"/></a></td>
			<td><!-- TMPL_VAR NAME=ALBUM --></td>
			<td><!-- TMPL_VAR NAME=TRACK --></td>
			<td><!-- TMPL_VAR NAME=TITLE --></td>
			<td><!-- TMPL_VAR NAME=ARTIST --></td>
			<td><!-- TMPL_VAR NAME=YEAR --></td>
			<td><!-- TMPL_VAR NAME=GENRE --></td>
			<td><!-- TMPL_VAR NAME=COMMENT --></td>
		</tr>
		<!-- /TMPL_LOOP -->
    </tbody>
</table>

</body>
</html>
HTML
my $tmpl = HTML::Template->new(scalarref => \$template);

    Complete Script

    The complete script is on github, you can have a look at –

    https://github.com/ajitabhpandey/learn-programming/blob/master/perl/id3-tags-manipulation/genCatalog.pl.

  • Build An MP3 Catalogue System With Perl – Basics

    My mp3 collection was increasing and I wanted to build a catalogue for the same. There are various steps in having even a simple catalogue system. In this post and a few posts that will follow, I will be explaining how to write such a system using perl as the programming language.

    MP3 Format and ID3 Tags

    MP3 is an audio coding format for digital audio. The audio data in this file is in a compressed format. The compression is a lossy compression, meaning the sound quality is not very clear. In spite of being a lossy format, it is one of the most popular format for audio streaming and storage. The mp3 file has built in bibliographic information such as title, artist, album. This information is stored in a field inside the file known as ID3 tag. Using this information, the MP3 players are able to display the Song Title, Album name and Artist name(s) etc.

    There are couple of versions of these ID3 tags in use. ID3v1 (1.1 being the last in version 1 series) and ID3v2 (ID3v2.4 being the latest version).

    Perl MP3::Tag Module

    The MP3::Tag module of perl can be used to read and write both the versions of the ID3 tag. Here are few of the sample perl programs to do that. This will help in understanding the usage of the modules before we proceed to the next steps.

    Below are couple of examples showing how to read ID3v1 and ID3v2 tags.

    #!/usr/bin/perl
#
# id3v1_read.pl
#
use 5.010;
use warnings;
use strict;
use MP3::Tag;

# set filename of MP3 track
my $filename = "your_mp3_file";

# create new MP3-Tag object
my $mp3 = MP3::Tag->new($filename);

# get tag information
$mp3->get_tags();

# check to see if an ID3v1 tag exists
# if it does, print track information
if (exists $mp3->{ID3v1}) {
  #$mp3->{ID3v1}->remove_tag();exit;

  say "Filename: $filename";
  say "Artist: " . $mp3->{ID3v1}->artist;
  say "Title: " . $mp3->{ID3v1}->title;
  say "Album: " . $mp3->{ID3v1}->album;
  say "Year: ". $mp3->{ID3v1}->year;
  say "Genre: " . $mp3->{ID3v1}->genre;
} else {
  say "$filename: ID3v1 tag not found";
}

# clean up
$mp3->close();

    ID3v2 tags are a bit more complex as they allow a lot more information to be stored in the MP3 file such as the album artwork etc. If you run the following script on one of your MP3 files it will print all the ID3v2 information to the screen. I have used the getc() function in order to allow you to observe the output and press <Enter> to proceed to the next set of key-value pair. After couple of keystrokes you will see there are lot of junk characters printed. These junk characters are nothing but the album artwork and following the junk characters is the MIME type of the artwork. In my case the MIME types were all “image/jpeg”.

    #!/usr/bin/perl
#
# id3v2_read.pl
#
use 5.010;
use warnings;
use strict;
use MP3::Tag;

# set filename of MP3 track
my $filename = "mp3_file_name;

# create new MP3-Tag object
my $mp3 = MP3::Tag->new($filename);

# get tag information
$mp3->get_tags();

# check to see if an ID3v2 tag exists
# if it does, print track information
if (exists $mp3->{ID3v2}) {
  # get a list of frames as a hash reference
  my $frames = $mp3->{ID3v2}->get_frame_ids();

  # iterate over the hash, process each frame
  foreach my $frame (keys %$frames) {
    # for each frame get a key-value pair of content-description
    my ($value, $desc) = $mp3->{ID3v2}->get_frame($frame);
    if (defined($desc) and length $desc) {
      say "$frame $desc: "; 
    } else {
      say "$frame :";
    }
    # sometimes the value is itself a hash reference containing more values
    # deal with that here
    if (ref $value eq "HASH") {
      while (my ($k, $v) = each (%$value)) {
        say "\n     - $k: $v";
      }
    } else {
      say "$value";
    }
    # allows to view each iteration
    getc(STDIN);
  }
} else {
  say "$filename: ID3v2 tag not found";
}

# clean up
$mp3->close();

    Next Steps

    Most of the current MP3 players read ID3v2 tags. It will be good to understand the structure of the ID3v2 tags, using one of the links I provided above. This will help you prepare for understanding the further articles in this series. In next part we will see how to extract desired information quickly and how to extract the artwork data from the MP3 file. Stay tuned for more.